Move subsurface-core to core and qt-mobile to mobile-widgets

Having subsurface-core as a directory name really messes with
autocomplete and is obviously redundant. Simmilarly, qt-mobile caused an
autocomplete conflict and also was inconsistent with the desktop-widget
name for the directory containing the "other" UI.

And while cleaning up the resulting change in the path name for include
files, I decided to clean up those even more to make them consistent
overall.

This could have been handled in more commits, but since this requires a
make clean before the build, it seemed more sensible to do it all in one.

Signed-off-by: Dirk Hohndel <dirk@hohndel.org>

mobile-widgets/qml/CloudCredentials.qml

@@ -0,0 +1,84 @@
+import QtQuick 2.3
+import QtQuick.Controls 1.2
+import QtQuick.Window 2.2
+import QtQuick.Dialogs 1.2
+import QtQuick.Layouts 1.1
+import org.kde.kirigami 1.0 as Kirigami
+import org.subsurfacedivelog.mobile 1.0
+
+Item {
+	id: loginWindow
+	height: outerLayout.height + 2 * Kirigami.Units.gridUnit
+
+	property string username: login.text;
+	property string password: password.text;
+
+	function saveCredentials() {
+		manager.cloudUserName = login.text
+		manager.cloudPassword = password.text
+		manager.saveCloudCredentials()
+	}
+
+	ColumnLayout {
+		id: outerLayout
+		width: subsurfaceTheme.columnWidth - 2 * Kirigami.Units.gridUnit
+
+		onVisibleChanged: {
+			if (visible && manager.accessingCloud < 0) {
+				manager.appendTextToLog("Credential scrn: show kbd was: " + (Qt.inputMethod.isVisible ? "visible" : "invisible"))
+				Qt.inputMethod.show()
+				login.forceActiveFocus()
+			} else {
+				manager.appendTextToLog("Credential scrn: hide kbd was: " + (Qt.inputMethod.isVisible ? "visible" : "invisible"))
+				Qt.inputMethod.hide()
+			}
+		}
+
+		Kirigami.Heading {
+			text: "Cloud credentials"
+			level: headingLevel
+			Layout.bottomMargin: Kirigami.Units.largeSpacing / 2
+		}
+
+		Kirigami.Label {
+			text: "Email"
+		}
+
+		TextField {
+			id: login
+			text: manager.cloudUserName
+			Layout.fillWidth: true
+			inputMethodHints: Qt.ImhEmailCharactersOnly |
+					  Qt.ImhNoAutoUppercase
+		}
+
+		Kirigami.Label {
+			text: "Password"
+		}
+
+		TextField {
+			id: password
+			text: manager.cloudPassword
+			echoMode: TextInput.Password
+			inputMethodHints: Qt.ImhSensitiveData |
+					  Qt.ImhHiddenText |
+					  Qt.ImhNoAutoUppercase
+			Layout.fillWidth: true
+		}
+		GridLayout {
+			columns: 2
+
+			CheckBox {
+				checked: false
+				id: showPassword
+				onCheckedChanged: {
+					password.echoMode = checked ? TextInput.Normal : TextInput.Password
+				}
+			}
+			Kirigami.Label {
+				text: "Show password"
+			}
+		}
+		Item { width: Kirigami.Units.gridUnit; height: width }
+	}
+}