mirror of
https://github.com/subsurface/subsurface.git
synced 2024-11-28 13:10:19 +00:00
9383693928
This is seriously flawed. makensis is run twice for some reason. I also noticed that the data and xslt directories under packaging/windows aren't created when running make install. Running make -f Makefile.Release install_marbledir install_deploy works, but obviously this should be taken care of by the dependency. The installed binary under Windows is not finding its icon, the translations are missing... lots of work left to do here. Signed-off-by: Dirk Hohndel <dirk@hohndel.org>
24 lines
1.1 KiB
Text
24 lines
1.1 KiB
Text
# Generate the ssrf-version.h file
|
|
VERSION_FILE = ssrf-version.h
|
|
macx: VER_OS = darwin
|
|
unix: !macx: VER_OS = linux
|
|
win32: VER_OS = win
|
|
exists(.git/HEAD): {
|
|
GIT_HEAD = .git/HEAD
|
|
VERSION_SCRIPT = $$PWD/scripts/get-version
|
|
# always use linux here -------------------vvv so we get the true full version
|
|
FULL_VERSION = "`$$VERSION_SCRIPT linux`"
|
|
PRODVERSION_STRING = $$system("sh scripts/get-version win $$FULL_VERSION || $${VERSION}.0.0")
|
|
VERSION_STRING = $$system("sh scripts/get-version linux $$FULL_VERSION || $${VERSION}")
|
|
version_h.depends = $$VERSION_SCRIPT $$PWD/.git/$$system("GIT_DIR=$$PWD/.git git rev-parse --symbolic-full-name HEAD")
|
|
version_h.commands = echo \\$${LITERAL_HASH}define VERSION_STRING \\\"`GIT_DIR=$$PWD/.git $$VERSION_SCRIPT $$VER_OS`\\\" > ${QMAKE_FILE_OUT}
|
|
version_h.input = GIT_HEAD
|
|
version_h.output = $$VERSION_FILE
|
|
version_h.variable_out = GENERATED_FILES
|
|
version_h.CONFIG = ignore_no_exist
|
|
QMAKE_EXTRA_COMPILERS += version_h
|
|
} else {
|
|
# This is probably a package
|
|
FULL_VERSION = $$VERSION
|
|
system(echo \\$${LITERAL_HASH}define VERSION_STRING \\\"$$VERSION\\\" > $$VERSION_FILE)
|
|
}
|